構造化プログラミング（2）

Sub Macro1()
    Dim a As Long, b As Long
    Dim g As Long

    a = Cells(1, 2).Value
    b = Cells(2, 2).Value

    g = ggcd(a, b)                     ' 関数を呼ぶだけ

    Cells(4, 1) = "最大公約数 GCD"
    Cells(4, 2) = g
    Cells(5, 1) = "最小公倍数 LCM"
    Cells(5, 2) = a * b / g            ' もとの a, b が残っているので使える

    ' 関数にしておけば、何組でも続けて呼べる
    Cells(7, 1) = "GCD(1071, 1029)"
    Cells(7, 2) = ggcd(1071, 1029)
    Cells(8, 1) = "GCD(17, 5)"
    Cells(8, 2) = ggcd(17, 5)
End Sub

Function ggcd(ByVal m As Long, ByVal n As Long) As Long
    Dim r As Long

    Do While n <> 0
        r = m Mod n                    ' 余りを求める
        m = n
        n = r
    Loop

    ggcd = m
End Function

Sub Macro2()
    Dim keshita(101) As Boolean       ' 消したかどうかを覚える
    Dim i As Integer, j As Integer
    Dim n As Integer
    Dim kosuu As Integer

    n = 100

    ' ② 2 から順に、まだ消されていなければ素数
    For i = 2 To n
        If keshita(i) = False Then
            ' ③ その倍数を消す（i*i から始めれば十分）
            For j = i * i To n Step i
                keshita(j) = True
            Next j
        End If
    Next i

    ' 表に並べる（10 列）
    For i = 1 To n
        Dim gy As Integer, rt As Integer
        gy = Int((i - 1) / 10) + 1
        rt = ((i - 1) Mod 10) + 1
        Cells(gy, rt) = i
        If i >= 2 And keshita(i) = False Then
            Cells(gy, rt).Interior.Color = RGB(198, 239, 206)   ' 素数
            kosuu = kosuu + 1
        Else
            Cells(gy, rt).Font.Color = RGB(180, 180, 180)
        End If
    Next i

    Cells(12, 1) = "素数の個数"
    Cells(12, 2) = kosuu
End Sub

Sub Macro3()
    Dim n As Integer

    Cells(1, 1) = "n": Cells(1, 2) = "fib(n)": Cells(1, 3) = "比 fib(n)/fib(n-1)"

    For n = 1 To 24
        Cells(n + 1, 1) = n
        Cells(n + 1, 2) = fib(n)
        If n >= 3 Then
            Cells(n + 1, 3) = Format(fib(n) / fib(n - 1), "#.########")
        End If
    Next n
End Sub

Function fib(ByVal n As Integer) As Long
    Dim i As Integer
    Dim a As Long, b As Long, t As Long

    If n <= 2 Then
        fib = 1
        Exit Function              ' ここで抜ける
    End If

    a = 1: b = 1                   ' fib(1), fib(2)
    For i = 3 To n
        t = a + b                  ' 次の値
        a = b                      ' ずらす
        b = t
    Next i

    fib = b
End Function

Dim zentai As Integer          ' モジュール変数（どこからも見える）

Sub Macro4()
    Dim i As Integer           ' Macro4 の i

    i = 100
    zentai = 5

    Cells(1, 1) = "Macro4 の i": Cells(1, 2) = i
    Cells(2, 1) = "zentai":      Cells(2, 2) = zentai

    Call betsuno

    ' betsuno の中で i を 999 にしたが……
    Cells(5, 1) = "呼んだあとの Macro4 の i"
    Cells(5, 2) = i
    Cells(6, 1) = "呼んだあとの zentai"
    Cells(6, 2) = zentai
End Sub

Sub betsuno()
    Dim i As Integer           ' こちらの i は別の箱

    i = 999                    ' Macro4 の i には影響しない
    zentai = zentai + 1        ' モジュール変数は共有されている

    Cells(3, 1) = "betsuno の i": Cells(3, 2) = i
End Sub

Sub Macro5()
    Dim i As Integer
    Dim a As Long, b As Long, g As Long

    Cells(1, 4) = "GCD": Cells(1, 5) = "LCM": Cells(1, 6) = "互いに素か"

    For i = 2 To 5
        a = Cells(i, 2).Value
        b = Cells(i, 3).Value

        g = ggcd(a, b)                  ' 部品①：最大公約数
        Cells(i, 4) = g
        Cells(i, 5) = a * b / g         ' 最小公倍数
        Cells(i, 6) = IIf(g = 1, "はい", "いいえ")

        If g = 1 Then Cells(i, 6).Interior.Color = RGB(255, 235, 156)
    Next i

    Cells(7, 1) = "関数が 1 つあるだけで、4 組ぶんが 1 つのループで片づく"
End Sub

Function ggcd(ByVal m As Long, ByVal n As Long) As Long
    Dim r As Long
    Do While n <> 0
        r = m Mod n
        m = n
        n = r
    Loop
    ggcd = m
End Function